Microsoft SQL Server 2008 對(duì) Transact-SQL 語(yǔ)言進(jìn)行了進(jìn)一步增強(qiáng)，主要包括：ALTER DATABASE 兼容級(jí)別設(shè)置、復(fù)合運(yùn)算符、CONVERT 函數(shù)、日期和時(shí)間功能、GROUPING SETS、MERGE 語(yǔ)句、SQL 依賴關(guān)系報(bào)告、表值參數(shù)和 Transact-SQL 行構(gòu)造函數(shù)。

　　1．ALTER DATABASE 兼容級(jí)別設(shè)置

　　某些數(shù)據(jù)庫(kù)行為與 SQL Server 版本有關(guān)，通過(guò) ALTER DATABASE 下面新增的語(yǔ)法，可以設(shè)置數(shù)據(jù)庫(kù)兼容級(jí)別，它取代了以前版本中的 sp_dbcmptlevel 過(guò)程。

ALTER DATABASE database_name
SET COMPATIBILITY_LEVEL = { 80 | 90 | 100 }

　　可用的設(shè)置值80、90、100分別代表 SQL Server 2000、2005和2008。

　　2．復(fù)合運(yùn)算符

　　SQL Server 2008 現(xiàn)在支持如下復(fù)合運(yùn)算符，可執(zhí)行操作并將變量設(shè)置為結(jié)果。

　　如：

DECLARE @x1 int = 27;
SET @x1 += 2 ;
SELECT @x1　-- 返回29

　　3．CONVERT 函數(shù)

　　CONVERT 函數(shù)現(xiàn)在允許在二進(jìn)制和字符十六進(jìn)制值之間進(jìn)行轉(zhuǎn)換。函數(shù)語(yǔ)法格式如下：

CONVERT ( data_type [ ( length ) ] , expression [ , style ] )

　　expression 是被轉(zhuǎn)換的有效的表達(dá)式，data_type 目標(biāo)數(shù)據(jù)類(lèi)型（不能使用別名數(shù)據(jù)類(lèi)型），length 指定目標(biāo)數(shù)據(jù)類(lèi)型長(zhǎng)度的可選整數(shù)，style 指定 CONVERT 函數(shù)如何轉(zhuǎn)換 的整數(shù)表達(dá)式。

　　如果 expression 為 binary(n)、varbinary(n)、char(n) 或 varchar(n)，則 style 可以為下表中顯示的值之一。

　　參考下面的示例代碼：

--轉(zhuǎn)換二進(jìn)制值 0x4E616d65 到一個(gè)字符值
SELECT CONVERT(char(8), 0x4E616d65, 0) AS 'Style 0, 二進(jìn)制到字符'
--下面的示例演示了 Style 為 1 的情況下,如何強(qiáng)行截?cái)嘟Y(jié)果值。
--產(chǎn)生的結(jié)果值由于包含字符 0x ，所以被截?cái)?br>SELECT CONVERT(char(8), 0x4E616d65, 1) AS 'Style 1, 二進(jìn)制到字符'
--下面的示例演示了 Style 為 2 的情況下，沒(méi)有截?cái)嘟Y(jié)果值。
--這是因?yàn)?0x 字符未包含在結(jié)果中
SELECT CONVERT(char(8), 0x4E616d65, 2) AS 'Style 2, 二進(jìn)制到字符'
--轉(zhuǎn)換字符值 Name 到一個(gè)二進(jìn)制值
SELECT CONVERT(binary(8), 'Name', 0) AS 'Style 0, 字符到二進(jìn)制'
SELECT CONVERT(binary(4), '0x4E616D65', 1) AS 'Style 1, 字符到二進(jìn)制'
SELECT CONVERT(binary(4), '4E616D65', 2) AS 'Style 2, 字符到二進(jìn)制'

　　結(jié)果如下：

　　4．日期和時(shí)間功能

　　DATEPART ( datepart , date )函數(shù)用于返回 date中的指定 datepart 的整數(shù)。如：

　　SELECT DATEPART(YEAR,'2007-05-10')　--返回2007

SQL Server 2008 包含對(duì) ISO 周-日期系統(tǒng)的支持，即周的編號(hào)系統(tǒng)。每周都與該周內(nèi)星期四所在的年份關(guān)聯(lián)。例如，2004 年第 1 周 (2004W01) 從 2003 年 12 月 29 日星期一到 2004 年 1 月 4 日星期天。一年中最大的周數(shù)可能為 52 或 53。這種編號(hào)方式通常用于歐洲國(guó)家，但其他國(guó)家/地區(qū)很少用到。

　　下面分別是2010年和2009年1月份的日歷。由于2010年第一 個(gè)星期中的星期四是2010-1-7日，所以2010-1-3日及之前的日期會(huì)作為2009年的第53個(gè)星期，而不是2010年的第一個(gè)星期。而對(duì)于 2009年1月份的日歷，由于星期四是2009-1-1，所以該星期會(huì)作為2009年的第一個(gè)星期。當(dāng)然，該星期也包含了2008-12-28至31的4 天。

　　參考下面的代碼：

SELECT DATEPART(ISO_WEEK,'2010-1-3')　--返回53
SELECT DATEPART(ISO_WEEK,'2010-1-4')　--返回1
SELECT DATEPART(ISO_WEEK,'2009-1-1')　--返回1

　　5．ROLLUP、CUBE 和GROUPING SETS

在SQL Server 2008之前，進(jìn)行分組統(tǒng)計(jì)匯總，可以在GROUP BY子句中使用WITH ROLLUP和WITH CUBE參數(shù)。ROLLUP指定在結(jié)果集內(nèi)不僅包含由GROUP BY提供的行，還包含匯總行。按層次結(jié)構(gòu)順序，從組內(nèi)的最低級(jí)別到最高級(jí)別匯總組。而CUBE參數(shù)則在使用ROLLUP參數(shù)所返回結(jié)果集的基礎(chǔ)上，再將每 個(gè)可能的組和子組組合在結(jié)果集內(nèi)返回。

　　例如，假設(shè)dbo.T1表中存在下列數(shù)據(jù)：

　　執(zhí)行下面的查詢語(yǔ)句：

SELECT CustName,ProductID,SUM(Sales) AS 'SalesTotal'
FROM dbo.T1
GROUP BY CustName,ProductID
WITH CUBE
ORDER BY CustName,ProductID;
　　
SELECT CustName,ProductID,SUM(Sales) AS 'SalesTotal'
FROM dbo.T1
GROUP BY CustName,ProductID
WITH ROLLUP
ORDER BY CustName,ProductID;

　　得到下面的結(jié)果集合，可以看出，使用WITH CUBE多出了對(duì)子組ProductID的兩行匯總。

而在SQL Server 2008中，GROUPING SETS、ROLLUP 和 CUBE 運(yùn)算符已添加到 GROUP BY 子句中。不再推薦使用不符合 ISO 的 WITH ROLLUP、WITH CUBE 和 ALL 語(yǔ)法。在SQL Server 2008中，可以將上面的WITH CUBE語(yǔ)句改寫(xiě)為如下的形式：

SELECT CustName,ProductID,SUM(Sales) AS 'SalesTotal'
FROM dbo.T1
GROUP BY CUBE(CustName,ProductID)
ORDER BY CustName,ProductID;

　　如果不需要獲得由完備的 ROLLUP 或 CUBE 運(yùn)算符生成的全部分組，則可以使用 GROUPING SETS 僅指定所需的分組。例如，下面的語(yǔ)句將得到分別按CustName和ProductID分組匯總結(jié)果集的并集。

SELECT CustName,ProductID,SUM(Sales) AS 'SalesTotal'
FROM dbo.T1
GROUP BY GROUPING SETS(CustName,ProductID)
ORDER BY CustName,ProductID;

　　結(jié)果集如下：

　　上面的語(yǔ)句等同于下面的UNION ALL語(yǔ)句：

SELECT CustName,NULL AS ProductID,SUM(Sales) AS 'SalesTotal'
FROM dbo.T1
GROUP BY CustName
UNION ALL
SELECT NULL AS CustName,ProductID,SUM(Sales) AS 'SalesTotal'
FROM dbo.T1
GROUP BY ProductID

　　6．MERGE 語(yǔ)句

在 SQL Server 2008 中，可以使用 MERGE 語(yǔ)句在一條語(yǔ)句中根據(jù)與源表聯(lián)接的結(jié)果對(duì)目標(biāo)表執(zhí)行 INSERT、UPDATE 或 DELETE 操作。如：使用一個(gè)語(yǔ)句有條件地在單個(gè)目標(biāo)表中插入或更新行，如果目標(biāo)表中存在相應(yīng)行，則更新一個(gè)或多個(gè)列；否則，會(huì)將數(shù)據(jù)插入新行。使用該語(yǔ)句還可以同 步兩個(gè)表，根據(jù)與源數(shù)據(jù)的差別在目標(biāo)表中插入、更新或刪除行。

　　MERGE 語(yǔ)法包括如下五個(gè)主要子句：

　　MERGE 子句用于指定作為插入、更新或刪除操作目標(biāo)的表或視圖。

　　USING 子句用于指定要與目標(biāo)聯(lián)接的數(shù)據(jù)源。

　　ON 子句用于指定決定目標(biāo)與源的匹配位置的聯(lián)接條件。

　　WHEN 子句用于根據(jù) ON 子句的結(jié)果指定要執(zhí)行的操作。

　　OUTPUT 子句針對(duì)更新、插入或刪除的目標(biāo)對(duì)象中的每一行返回一行。

　　其完整的語(yǔ)法格式如下：

[ WITH <common_table_expression> [,...n] ]
MERGE
　　　　[ TOP ( expression ) [ PERCENT ] ]
　　　　[ INTO ] target_table [ WITH ( <merge_hint> ) ] [ [ AS ] table_alias ]
　　　　USING <table_source>
　　　　ON <merge_search_condition>
　　　　[ WHEN MATCHED [ AND <clause_search_condition> ]
　　　　　　THEN <merge_matched> ]
　　　　[ WHEN NOT MATCHED [ BY TARGET ] [ AND <clause_search_condition> ]
　　　　　　THEN <merge_not_matched> ]
　　　　[ WHEN NOT MATCHED BY SOURCE [ AND <clause_search_condition> ]
　　　　　　THEN <merge_matched> ]
　　　　[ <output_clause> ]
　　　　[ OPTION ( <query_hint> [ ,...n ] ) ]

　　使用下面的語(yǔ)句創(chuàng)建兩個(gè)表：

USE AdventureWorks;
GO
IF OBJECT_ID (N'dbo.Purchases', N'U') IS NOT NULL
　　DROP TABLE dbo.Purchases;
GO
CREATE TABLE dbo.Purchases (
　　ProductID int, CustomerID int, PurchaseDate datetime,
　　CONSTRAINT PK_PurchProdID PRIMARY KEY(ProductID,CustomerID));
GO
INSERT INTO dbo.Purchases VALUES(707, 11794, '20060821'),
(707, 15160, '20060825'),(708, 18529, '20060821'),
(712, 19072, '20060821'),(870, 15160, '20060823'),
(870, 11927, '20060824'),(870, 18749, '20060825');
GO
IF OBJECT_ID (N'dbo.FactBuyingHabits', N'U') IS NOT NULL
　　DROP TABLE dbo.FactBuyingHabits;
GO
CREATE TABLE dbo.FactBuyingHabits (
　　ProductID int, CustomerID int, LastPurchaseDate datetime,
　　CONSTRAINT PK_FactProdID PRIMARY KEY(ProductID,CustomerID));
GO
INSERT INTO dbo.FactBuyingHabits VALUES(707, 11794, '20060814'),
(707, 18178, '20060818'),(864, 14114, '20060818'),
(870, 17151, '20060818'),(870, 15160, '20060817'),
(871, 21717, '20060817'),(871, 21163, '20060815'),
(871, 13350, '20060815'),(873, 23381, '20060815');
GO

　　兩個(gè)表中的數(shù)據(jù)如下圖所示：

請(qǐng)注意，這兩個(gè)表中有兩個(gè)共有的產(chǎn)品-客戶行：客戶 11794 購(gòu)買(mǎi)了產(chǎn)品 707，客戶 15160 購(gòu)買(mǎi)了產(chǎn)品 870。對(duì)于這些行，可以使用 WHEN MATCHED THEN 子句利用 Purchases 中這些購(gòu)買(mǎi)記錄的日期來(lái)更新 FactBuyingHabits。我們可以使用 WHEN NOT MATCHED THEN 子句將所有其他行插入 FactBuyingHabits。參考下面的語(yǔ)句：

MERGE dbo.FactBuyingHabits AS Target
USING (SELECT CustomerID, ProductID, PurchaseDate FROM dbo.Purchases) AS Source
ON (Target.ProductID = Source.ProductID AND Target.CustomerID = Source.CustomerID)
WHEN MATCHED THEN
　　UPDATE SET Target.LastPurchaseDate = Source.PurchaseDate
WHEN NOT MATCHED BY TARGET THEN
　　INSERT (CustomerID, ProductID, LastPurchaseDate)
　　VALUES (Source.CustomerID, Source.ProductID, Source.PurchaseDate)
OUTPUT $action, Inserted.*, Deleted.*;

$action用于在 OUTPUT 子句中指定一個(gè) nvarchar(10) 類(lèi)型的列，列的值是代表所執(zhí)行操作的INSERT、UPDATE或DELETE。Inserted.*和Deleted.*分別用于指定返回所有插入行的 列和刪除行的列。如果要指定具體的列，可以使用Inserted.ProductID這樣的命名方式。

　　上面語(yǔ)句的輸出結(jié)果如下：

　　再查詢FactBuyingHabits表，可以看到被更新和插入后的結(jié)果，如下所示：

　　7．SQL 依賴關(guān)系報(bào)告

SQL Server 2008 引入了新的目錄視圖和系統(tǒng)函數(shù)用以提供一致可靠的 SQL 依賴關(guān)系報(bào)告。所謂依賴關(guān)系，通俗的講：存儲(chǔ)過(guò)程1需要使用存儲(chǔ)過(guò)程2提供的結(jié)果，它們之間就是一種依賴關(guān)系?？梢允褂? sys.sql_expression_dependencies、sys.dm_sql_referencing_entities 和 sys.dm_sql_referenced_entities 來(lái)報(bào)告架構(gòu)綁定和非架構(gòu)綁定對(duì)象的跨服務(wù)器、跨數(shù)據(jù)庫(kù)和數(shù)據(jù)庫(kù) SQL 依賴關(guān)系。

　　下例將創(chuàng)建一個(gè)表、一個(gè)視圖和三個(gè)存儲(chǔ)過(guò)程。這些對(duì)象將用在后面的查詢中以演示如何報(bào)告依賴關(guān)系信息?？煽吹?MyView 和 MyProc3 均引用 Mytable。MyProc1 引用 MyView，而 MyProc2 引用 MyProc1。

USE AdventureWorks;
GO
-- Create entities
CREATE TABLE dbo.MyTable (c1 int, c2 varchar(32));
GO
CREATE VIEW dbo.MyView
AS SELECT c1, c2 FROM dbo.MyTable;
GO
CREATE PROC dbo.MyProc1
AS SELECT c1 FROM dbo.MyView;
GO
CREATE PROC dbo.MyProc2
AS EXEC dbo.MyProc1;
GO
CREATE PROC dbo.MyProc3
AS SELECT * FROM AdventureWorks.dbo.MyTable;
　 EXEC dbo.MyProc2;
GO

　　下面的示例查詢 sys.sql_expression_dependencies 目錄視圖以返回由 MyProc3 引用的實(shí)體。

USE AdventureWorks;
GO
SELECT OBJECT_NAME(referencing_id) AS referencing_entity_name
　　,referenced_server_name AS server_name
　　,referenced_database_name AS database_name
　　,referenced_schema_name AS schema_name
　　, referenced_entity_name
FROM sys.sql_expression_dependencies
WHERE referencing_id = OBJECT_ID(N'dbo.MyProc3');
GO

　　下面是結(jié)果集：

referencing_entity server_name database_name　schema_name referenced_entity
------------------　 -----------　　-------------　　 ----------- --　　---------------
MyProc3　　　　　　NULL　　　　NULL　　　　　 dbo　　　　 MyProc2
MyProc3　　　　　　NULL　　　　AdventureWorks　 dbo　　　　 MyTable

　　上面的查詢返回了兩個(gè)在 MyProc3 定義中按名稱引用的實(shí)體。服務(wù)器名稱為 NULL，因?yàn)楸灰脤?shí)體沒(méi)有使用有效的由四部分組成的名稱指定。返回的結(jié)果中顯示了 MyTable 的數(shù)據(jù)庫(kù)名稱，因?yàn)樵诖鎯?chǔ)過(guò)程中是使用由三部分組成的有效名稱定義此實(shí)體的。

　　8．表值參數(shù)

數(shù)據(jù)庫(kù)引擎引入了可以引用用戶定義表類(lèi)型的新參數(shù)類(lèi)型。表值參數(shù)可以將多個(gè)數(shù)據(jù)行發(fā)送到 SQL Server 語(yǔ)句或例程（比如存儲(chǔ)過(guò)程或函數(shù)），而不用創(chuàng)建臨時(shí)表。表值參數(shù)具有更高的靈活性，在某些情況下，可比臨時(shí)表或其他傳遞參數(shù)列表的方法提供更好的性能。表 值參數(shù)具有以下優(yōu)勢(shì)：

　　首次從客戶端填充數(shù)據(jù)時(shí)，不獲取鎖。

　　提供簡(jiǎn)單的編程模型。

　　允許在單個(gè)例程中包括復(fù)雜的業(yè)務(wù)邏輯。

　　減少到服務(wù)器的往返。

　　可以具有不同基數(shù)的表結(jié)構(gòu)。

　　是強(qiáng)類(lèi)型。

　　使客戶端可以指定排序順序和唯一鍵。

　　與其他參數(shù)一樣，表值參數(shù)的作用域也是存儲(chǔ)過(guò)程、函數(shù)或動(dòng)態(tài) Transact-SQL 文本。同樣，表類(lèi)型變量也與使用 DECLARE 語(yǔ)句創(chuàng)建的其他任何局部變量一樣具有作用域。

　　與BULK INSERT操作相比，頻繁使用表值參數(shù)將比大型數(shù)據(jù)集要快。大容量操作的啟動(dòng)開(kāi)銷(xiāo)比表值參數(shù)大，與之相比，表值參數(shù)在插入數(shù)目少于 1000 的行時(shí)具有很好的執(zhí)行性能。

　　下面是SQL Server幫助中的示例，演示了如何執(zhí)行以下操作：創(chuàng)建表值參數(shù)類(lèi)型，聲明變量來(lái)引用它，填充參數(shù)列表，然后將值傳遞到存儲(chǔ)過(guò)程。

USE AdventureWorks;
GO
　　
/* 創(chuàng)建一個(gè)table類(lèi)型 */
CREATE TYPE LocationTableType AS TABLE
( LocationName VARCHAR(50)
, CostRate INT );
GO
　　
/* 創(chuàng)建一個(gè)存儲(chǔ)過(guò)程，用于從表值參數(shù)接收數(shù)據(jù) */
CREATE PROCEDURE usp_InsertProductionLocation
　　@TVP LocationTableType READONLY
　　AS
　　SET NOCOUNT ON
　　INSERT INTO [AdventureWorks].[Production].[Location]
　　　　　 ([Name]
　　　　　 ,[CostRate]
　　　　　 ,[Availability]
　　　　　 ,[ModifiedDate])
　　　　SELECT *, 0, GETDATE()
　　　　FROM　@TVP;
　　　　GO
　　
/* 定義一個(gè)引用表值類(lèi)型的變量 */
DECLARE @LocationTVP
AS LocationTableType;
　　
/* 添加數(shù)據(jù)到表值變量 */
INSERT INTO @LocationTVP (LocationName, CostRate)
　　SELECT [Name], 0.00
　　FROM
　　[AdventureWorks].[Person].[StateProvince];
　　
/* 傳遞表值變量數(shù)據(jù)給存儲(chǔ)過(guò)程 */
EXEC usp_InsertProductionLocation @LocationTVP;
GO

　　9．Transact-SQL 行構(gòu)造函數(shù)

增強(qiáng)后的 Transact-SQL 可以允許將多個(gè)值插入單個(gè) INSERT 語(yǔ)句中，語(yǔ)法比較簡(jiǎn)單。參考下面的代碼：
/* 創(chuàng)建一個(gè)表 */
CREATE TABLE dbo.T1(
CustName char(20) ,
ProductID int ,
MadeFrom char(20) ,
Sales numeric(20, 2)
)
　　
/* 插入2行數(shù)據(jù) */
INSERT INTO dbo.T1
VALUES ('Jane',1,'China',20.00),
　　　 ('Jack',2,'USA',10.00)