|
自用通達信公式：均線、KDJ、MACD指標等
---------------------------指標公式----------------------------------
一、變色移動平均線
P1=5;P2=20;N=10 畫線方法：主圖疊加
MA1:MA(CLOSE,M1),COLORRED;
MA2:MA(CLOSE,M2),COLORMAGENTA;
上軌:MA2*(1+P1/100),COLORMAGENTA;｛畫一條正乖離線｝
下軌:MA2*(1-P1/100),COLORMAGENTA;｛畫一條負乖離線｝
上升:IF(MA1>REF(MA1,1),MA1,DRAWNULL),COLORRED,LINETHICK2;｛MA1上升的時候畫紅色｝
下降:IF(MA1<REF(MA1,1),MA1,DRAWNULL),COLORBLUE,LINETHICK2;｛MA1下降的時候畫藍色色｝
上:IF(MA2>REF(MA2,1),MA2,DRAWNULL),COLORRED,LINETHICK2;
下:IF(MA2<REF(MA2,1),MA2,DRAWNULL),COLORFF9966,LINETHICK2;
STICKLINE(MA1>0,MA1,MA1,0.8,1),COLORYELLOW;
二、KDJ分段線源碼:
N=9;M1=3;M2=3
RSV:=(CLOSE-LLV(LOW,N))/(HHV(HIGH,N)-LLV(LOW,N))*100;
K:SMA(RSV,M1,1),COLORGRAY;
D:SMA(K,M2,1),COLORBLUE;
J:3*K-2*D;
{IF(K<REF(K,1),K,DRAWNULL),COLORGREEN,LINETHICK1;
IF(D<REF(D,1),D,DRAWNULL),COLORGREEN,LINETHICK1;}
IF(J<REF(J,1),J,DRAWNULL),COLORFFFF00,LINETHICK1;
{IF(K>REF(K,1),K,DRAWNULL),COLORRED,LINETHICK1;
IF(D>REF(D,1),D,DRAWNULL),COLORRED,LINETHICK1;}
IF(J>REF(J,1),J,DRAWNULL),COLORFF00FF,LINETHICK1;
STICKLINE(J>-100,J,J,0.8,1),COLORYELLOW;
三、MACD變色
附圖公式，變色MACD
DIF1:EMA(CLOSE,12) - EMA(CLOSE,26),LINETHICK1,COLORYELLOW;
DEA1:EMA(DIF1,9),COLORGRAY;
MACD1:2*(DIF1-DEA1),COLORSTICK;
IF(DIF1<REF(DIF1,1),DIF1,DRAWNULL),COLORBLUE,LINETHICK1;
IF(DIF1>REF(DIF1,1),DIF1,DRAWNULL),COLORRED,LINETHICK1;
IF(DIF1=REF(DIF1,1),DIF1,DRAWNULL),COLORWHITE,LINETHICK1;
STICKLINE(DIF1>=REF(DIF1,1),DIF1,DIF1,1,8),COLORYELLOW;
{STICKLINE(MACD1>REF(MACD1,1),0,MACD1,1,0),COLORGREEN;}
STICKLINE(DIF1<REF(DIF1,1),DIF1,DIF1,1,8),COLORYELLOW;
DRAWTEXT(CROSS(DIF1,DEA1),DEA1,'←金叉'),COLORRED;
DRAWTEXT(CROSS(DEA1,DIF1),DEA1,'←死叉'),COLORYELLOW;
STICKLINE(MACD1>REF(MACD1,1),0,MACD1,1,0),COLORRED;
STICKLINE(MACD1<REF(MACD1,1),0,MACD1,1,0),COLORCBCBC0;
四：量比
V5:=MA(VOL,5);
量比:VOL/V5,VOLSTICK;
五：成交量
M1=5；M2=10；M3=60
VOLUME:VOL,VOLSTICK;
MAVOL1:MA(VOLUME,M1);
MAVOL2:MA(VOLUME,M2);
MAVOL3:MA(VOLUME,M3);
STICKLINE(VOLUME>MAVOL3,VOLUME,0,0.5,0),COLORMAGENTA;{用于觀察明顯的放量：成交量大于60日均量線畫紫色柱線}
---------------------------選股公式----------------------------------
一、KDJ選股公式：J小于P（P=40）
RSV:=(CLOSE-LLV(LOW,N))/(HHV(HIGH,N)-LLV(LOW,N))*100;
K:=SMA(RSV,M1,1);
D:=SMA(K,M2,1);
J:=3*K-2*D;
J<P;
二、量比選股公式：P=2
V5:=MA(VOL,5);
量比:=VOL/V5;
量比>P;
三、5日均線連續(xù)下行4日后向上拐頭
參數(shù)：P=5
MA1:=MA(CLOSE,P);
{選股條件}MA1>REF(MA1,1) AND REF(MA1,1)<REF(MA1,2)
AND REF(MA1,2)<REF(MA1,3)
AND REF(MA1,3)<REF(MA1,4)
AND REF(MA1,4)<REF(MA1,5);
再建一個交易系統(tǒng)公式，配合上面的選股公式，可以在主圖上單擊右鍵，然后點“專家指示”－“交易系統(tǒng)指示”顯示出買入信號：
參數(shù)：P1=5
MA1:=MA(CLOSE,P1);
{多頭買入} ENTERLONG:MA1>=REF(MA1,1)
AND REF(MA1,1)<REF(MA1,2)
AND REF(MA1,2)<REF(MA1,3)
AND REF(MA1,3)<REF(MA1,4)
AND REF(MA1,4)<REF(MA1,5);
{多頭賣出} EXITLONG:(CLOSE-REF(CLOSE,1))/REF(CLOSE,1)*100>20;
四、當前20日均線保持向上（用于選出中期趨勢向上的股票）
參數(shù)：P=20
MA1:=MA(CLOSE,P);
X:=MA1>REF(MA1,1);
N:=COUNT(X,6);{COUNT(X,N),統(tǒng)計N周期中滿足X條件的周期數(shù),若N=0則從第一個有效值開始.
例如:COUNT(CLOSE>OPEN,20)表示統(tǒng)計20周期內收陽的周期數(shù)}
N>5;
--------------------------五彩K線公式----------------------------------------
一、N日均線之上
MA1:=MA(CLOSE,N);
K:MA1>REF(MA1,1),COLORLIRED;
二、收盤價大于P日均線,畫淡紅色；收盤價小于P日均線,畫棕色
參數(shù)：P＝5
MA1:=MA(CLOSE,P);
CLOSE>MA1,COLORLIRED;
CLOSE<MA1,COLORBROWN;
參考文件：通達信變色線形的應用（作者：浩申）
http://bbs./viewthread.php?tid=1023344&extra=page%3D1
|
