大智慧公式入門

閃電的味道 2012-04-17

展開全文

5、函數(shù):STICKLINE 說明:在圖形上繪制柱線。
用法： STICKLINE(COND,PRICE1,PRICE2,WIDTH,EMPTY),當COND條件滿足時,在PRICE1和PRICE2位置之間畫柱狀線，寬度為WIDTH可為0---100(10為標準間距),EMPTH不為0則畫空心柱。
示例:STICKLINE(CLOSE>OPEN,CLOSE,OPEN,4,1);表示畫K線中陽線的空心柱體部分。
運用要點：
⑴PRICE1和PRICE2沒有順序關系，即何者在前何者在后都不影響語句的執(zhí)行。
⑵WIDTH寬度，支持小數(shù)。用1和用0.1，會有很大的差別。取4時和主圖的K線寬度差不多。
以下的副圖公式，畫出的K線，與主圖中顯示的K線差不多。
指標示例：
{副圖K線}
STICKLINE(C>O OR (C=O AND C>REF(C,1)),O,C,4,1),colorred;{畫出紅K實體}
STICKLINE((C>O AND C<>H) OR (C=O AND C>REF(C,1)),C,H,0.1,0),colorred;{畫出紅K上影線}
STICKLINE((C>O AND L<>O) OR (C=O AND C>REF(C,1)),L,O,0.1,0),colorred;{畫出紅K下影線}
STICKLINE(C<O OR (C=O AND C<=REF(C,1)),C,O,4,0),colorffcc66;{畫出青K實體}
STICKLINE(C<O OR (C=O AND C<=REF(C,1)),L,H,0.1,0),colorffcc66;{畫出青K影線。因為青K是實心的，所以影線從中穿過}
ma5:MA(C,5),colorwhite;
ma10:ma(c,10),colorff00ff;
繪圖函數(shù)結合示例介紹完了，相信你一定有所收獲吧，舉一反三自己動手編個指標。不要怕失敗，失敗是成功之母。
三背景裝飾
飛狐、分析家股軟能將背景顏色通過漸變顏色函數(shù)裝扮的很漂亮，那么大智慧股軟能做到嗎？能，但做出的背景色雖不如飛狐、分析家平滑漂亮，也能起到裝扮的作用，效果也可以。
在大智慧設計背景色的原理主要是通過主、副圖的坐標用畫柱線函數(shù)STICKLINE或者設定坐標用顏色代碼就可以完成。下面用實例來說明背景色的設計過程。
一、單色背景色，這是最簡單實用的一種裝飾方法。我們先來設計一個主圖指標：
要領：1、設定坐標：STICKLINE(CLOSE>0,h*9.0,l*0.01,8,0),color7d7f0f;意思是CLOSE>0條件滿足時，在坐標h*9.0至坐標l*0.01處畫寬度為8的實體柱線(也就是在整個主圖上添色)。
也可以這樣設定STICKLINE(110,0,110,8,0),color7d7f0f;顯示的是同樣效果。
2、添色的源碼必須在指標的頭條位置上，否則會覆蓋均線、K線、文字等圖形。
3、必須另外編制K線，因為背景色會覆蓋系統(tǒng)中的K線圖。
4、可以把背景色分為五檔、十擋或更多，同時注意與你的指標的最大值、最小值(也就是坐標)相匹配，否則會在指標中出現(xiàn)背景色殘缺不全的情況。
5、用你喜歡的顏色需要結合調色器可隨意自定義自己喜歡的顏色。不過可得有耐心啊！
指標示例一：
{多空密碼主圖}
STICKLINE(CLOSE>0,h*9.0,l*0.01,8,0),color7d7f0f;{設置背景，可以將這句源碼復制粘貼到任意主圖指標的頭條位置上}
Var1:=(3*CLOSE+LOW+OPEN+HIGH)/6;
Var3:=(20*Var1+19*REF(Var1,1)+18*REF(Var1,2)+17*REF(Var1,3)+16*REF(Var1,4)+15*REF
(Var1,5)+14*REF(Var1,6)+13*REF(Var1,7)+12*REF(Var1,8)+11*REF(Var1,9)+10*REF
(Var1,10)+9*REF(Var1,11)+8*REF(Var1,12)+7*REF(Var1,13)+6*REF(Var1,14)+5*REF
(Var1,15)+4*REF(Var1,16)+3*REF(Var1,17)+2*REF(Var1,18)+REF(Var1,20))/221;
Var4:=MA(Var3,78),LINETHICK2;
Var5:=EMA(MA(CLOSE,3),34);
Var6:=MA(Var3,5);
Var7:=MA(Var3,9);
M60:MA(C,60),COLOREEFFFF,CIRCLEDOT;
STICKLINE(Var3>1.005*Var4,Var3,Var4,4,1),COLORYELLOW;
STICKLINE(IF(Var3<Var5,Var3<=1.015*Var4,Var3<=1.005*Var4),Var7,Var4,2,1),COLORffff88;
STICKLINE(Var3>Var6,Var3,Var7,4,1),COLORff88ff;
STICKLINE(IF(Var3<Var6,Var3<=1.015*Var6,Var3<=1.005*Var6),Var3,Var7,3,1),COLORFF6633;
STICKLINE(Var3>Var6,Var3,Var7,4,1),COLOR0000ff;
{下面是柱形K線，如果喜歡這樣的K線，你可以復制粘貼到任意主圖指標里面}
STICKLINE(C>=O,C,O,7,0),COLORRED;
STICKLINE(C>=O,C,O,4,0),COLOR7070ff;
STICKLINE(C>=O,C,O,2,0),COLORYELLOW;
STICKLINE(C>=O,H,L,0,0),COLORYELLOW;
STICKLINE(C<=O,C,O,7,0),COLORFF2020;
STICKLINE(C<=O,C,O,4,0),COLORFF6600;
STICKLINE(C<=O,C,O,2,0),colorffcc66;
STICKLINE(C<=O,H,L,0,0),colorffcc66;
M9:MA(C,9),COLORYELLOW;
生命線: MA(CLOSE,13),COLORYELLOW,LINETHICK2;
牛熊線: (EMA(CLOSE,5)*7+EMA(CLOSE,5)*3)/10,COLORFF00CC,LINETHICK2;
箱頂:MA(REF(HHV(CLOSE,30),1),2);
箱底:MA(REF(LLV(CLOSE,30),1),2);
AA:(MA(C,13)+MA(C,21)+MA(C,34)+MA(C,55))/4,COLORFF00FF;
半年線:ma(close,125),colorffcc66;
指標示例二：
{財出水面副圖}
VAR2:=(CLOSE-LLV(LOW,20))/(HHV(HIGH,20)-LLV(LOW,20))*100;
VAR3:=SMA(SMA(VAR2,3,1),3,1)/28.57;
VAR4:=EMA(VAR3,5);
操盤:=3*VAR3-2*VAR4;
A1:=CROSS(操盤,VAR3) AND VAR3<2.1 and c>o;
40,colorred,pointdot;
STICKLINE(c>0,40,22,8,0),colorff8080;{設置背景,CLOSE>0條件滿足時，在坐標40至坐標22處設置寬度為8的蘭色背景}
STICKLINE(c>0,22,4,8,0),color916f87;{設置背景,CLOSE>0條件滿足時，在坐標22至坐標4處設置寬度為8的深紫色背景}
stickline(a1,18,15,28,0),colorred;
stickline(a1,18,18,18,0),colorblue;
stickline(a1,8,8,9,0),colorffff00;
stickline(a1,6,6,4,0),colorffff00;
stickline(a1,10,10,12,0),colorffff00;
stickline(a1,12,12,20,0),colorffff00;
stickline(a1,14,14,24,0),colorffff00;
stickline(a1,16,34,0.1,0),colorc0c0c0;
stickline(a1,33,18,9,0),colorwhite;
drawtext(a1,36,'財出水面'),COLORWHITE;
VarE:=30+(REF(CLOSE,1)-REF(OPEN,1))/REF(OPEN,1)*100/1.5;
VarF:=30+(REF(CLOSE,2)-REF(OPEN,2))/REF(OPEN,2)*100/1.5;
Var10:=CROSS("KDJ.K"(9,3,3),"KDJ.J"(9,3,3)) AND "KDJ.D"(9,3,3)>13;
Var11:=CROSS(REF("KDJ.K"(9,3,3),1),REF("KDJ.J"(9,3,3),1)) AND REF("KDJ.D"(9,3,3),1)>13;
Var12:=CROSS(REF("KDJ.K"(9,3,3),2),REF("KDJ.J"(9,3,3),2)) AND REF("KDJ.D"(9,3,3),2)>12;
Var13:=Var10 OR Var11 OR Var12;
Var14:=REF("BIAS.BIAS2"(6,12,24),1)>2;
Var15:=REF("RSI.RSI1"(6,12,24),1)>(VarE+VarF)/1.8 AND REF("ROC.ROC"(12,6),1)-"ROC.ROC"(12,6)>0 AND Var13 AND Var14;
賣出:=Var15*100/15,color00ff00;
stickline(賣出,18,15,28,0),coloryellow;
stickline(賣出,18,18,18,0),colorblue;
stickline(賣出,8,8,9,0),colorffff00;
stickline(賣出,6,6,4,0),colorffff00;
stickline(賣出,10,10,12,0),colorffff00;
stickline(賣出,12,12,20,0),colorffff00;
stickline(賣出,14,14,24,0),colorffff00;
stickline(賣出,16,28,0.1,0),colorc0c0c0;
stickline(賣出,28,18,9,0),color00ff00;
drawtext(賣出,31,'落袋為安'),COLOR00FF00;
指標示例三：
{金叉死叉}
STICKLINE(100,0,100,8,0),colorff0098;{設置背景,100條件滿足時，在坐標100至坐標0處設置寬度為8的紫蘭色背景}
Var1:=EMA(HHV(HIGH,500),21);
Var2:=EMA(HHV(HIGH,250),21);
Var3:=EMA(HHV(HIGH,90),21);
Var4:=EMA(LLV(LOW,500),21);
Var5:=EMA(LLV(LOW,250),21);
Var6:=EMA(LLV(LOW,90),21);
Var7:=EMA((Var4*0.96+Var5*0.96+Var6*0.96+Var1*0.558+Var2*0.558+Var3*0.558)/6,21); Var8:=EMA((Var4*1.25+Var5*1.23+Var6*1.2+Var1*0.55+Var2*0.55+Var3*0.65)/6,21);
Var9:=EMA((Var4*1.3+Var5*1.3+Var6*1.3+Var1*0.68+Var2*0.68+Var3*0.68)/6,21);
VarA:=EMA((Var7*3+Var8*2+Var9)/6*1.738,21);
VarB:=REF(LOW,1);
VarC:=SMA(ABS(LOW-VarB),3,1)/SMA(MAX(LOW-VarB,0),3,1)*100;
VarD:=EMA(IF(CLOSE*1.35<=VarA,VarC*10,VarC/10),3);
VarE:=LLV(LOW,30);
VarF:=HHV(VarD,30);
Var10:=IF(MA(CLOSE,58),1,0);
Var11:=EMA(IF(LOW<=VarE,(VarD+VarF*2)/2,0),3)/618*Var10;
Var12:=IF(Var11>40,10,Var11);
STICKLINE(Var12>8,0,Var12,4,1), , COLORFF00FF;
Var13:=HHV(HIGH,30);
Var14:=LLV(LOW,30);
能量K:EMA((CLOSE-Var14)/(Var13-Var14)*97,5),COLORRED,linethick2;
能量D:EMA((CLOSE-Var14)/(Var13-Var14)*100,15),linethick2,colorff9933;
底部峰:5,pointdot,linethick2,COLORFF00FF;
DRAWTEXT(CROSS(底部峰,能量K),能量d,'●'),COLORWHITE;
DRAWTEXT(CROSS(底部峰,能量K),能量K+15,'底部形成'),COLORWHITE;
大智慧:100,,pointdot,linethick2,color00ccff;
強弱分界:50,pointdot,COLORWHITE;
DRAWTEXT(CROSS(90,能量K),80,'●'),COLOR00FF00;
DRAWTEXT(CROSS(90,能量K),90,'有風險'),COLOR00FF00;
DRAWTEXT(CROSS(90,能量K),能量K+13,'●'),COLOR00FF00;
DRAWTEXT(CROSS(能量D,能量K),98,'死叉'),COLORFFCC66;
DRAWTEXT(CROSS(能量D,能量K),90,'●'),COLORFFCC66;
DRAWTEXT(CROSS(能量K,能量D),8,'金叉'),COLORYELLOW;
DRAWTEXT(CROSS(能量K,能量D),15,'●'),COLORYELLOW;
0,pointdot,linethick2,COLORFF00FF;