先看一個(gè)非多線程的例子, 代碼執(zhí)行時(shí)不能進(jìn)行其它操作(譬如拖動(dòng)窗體):

---

{自定義方法: 在窗體上繪制...}
procedure MyMethod;
var
  i: Integer;
begin
  for i := 0 to 500000 do
  begin
    Form1.Canvas.Lock;
    Form1.Canvas.TextOut(10, 10, IntToStr(i));
    Form1.Canvas.Unlock;
  end;
end;

{調(diào)用上面的自定義方法}
procedure TForm1.Button1Click(Sender: TObject);
begin
  MyMethod;
end;

---

修改為多線程(只修改一行代碼):

---

procedure MyMethod;
var
  i: Integer;
begin
  for i := 0 to 500000 do
  begin
    Form1.Canvas.Lock;
    Form1.Canvas.TextOut(10, 10, IntToStr(i));
    Form1.Canvas.Unlock;
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  TThread.CreateAnonymousThread(MyMethod).Start; //!!!
end;

---

代碼分析:

1、TThread 現(xiàn)在增加了許多 class 方法(直接通過類名調(diào)用的方法), TThread.CreateAnonymousThread() 就是比較有用的一個(gè).

2、顧名思義, CreateAnonymousThread 是建立匿名線程對象, 它的參數(shù)是我們需要在線程中執(zhí)行的方法.

3、但 CreateAnonymousThread 建立線程后是掛起的, 需要手動(dòng)運(yùn)行它; 后面的 Start 方法就是用來喚醒線程的.

4、(以前)喚醒線程還可以使用 Resume 方法或 Suspended 屬性(Suspended := False;); 但它們即將被廢棄了, 現(xiàn)在應(yīng)使用 Start 來啟動(dòng)線程.

---

CreateAnonymousThread 的參數(shù)類型 TProc 是匿名方法(reference), 所以代碼可以簡寫為:

---

procedure TForm1.Button1Click(Sender: TObject);
begin
  TThread.CreateAnonymousThread( //直接寫入方法體
    procedure
    var
      i: Integer;
    begin
      for i := 0 to 500000 do
      begin
        Canvas.Lock;
        Canvas.TextOut(10, 10, IntToStr(i));
        Canvas.Unlock;
      end;
    end //此處無分號
  ).Start;
end;

---

延時(shí)執(zhí)行:

---

var
  myThread: TThread;

procedure TForm1.FormCreate(Sender: TObject);
begin
  myThread := TThread.CreateAnonymousThread(
    procedure
    var
      i: Integer;
    begin
      for i := 0 to 500000 do
      begin
        Canvas.Lock;
        Canvas.TextOut(10, 10, IntToStr(i));
        Canvas.Unlock;
      end;
    end
  );
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  myThread.Start;
end;

---