問(wèn)題來(lái)源: http://www.cnblogs.com/del/archive/2009/10/09/1579614.html#1779614

這幾天家有病人, 幾天沒(méi)上網(wǎng)了; 看到這個(gè)問(wèn)題我會(huì), 順便回復(fù)了.

---

發(fā)送代碼:

---

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Edit1: TEdit;
    procedure Button1Click(Sender: TObject);
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.Button1Click(Sender: TObject);
var
  h: HWND;
  Size: Integer;
  CopyDataStruct: TCopyDataStruct;
begin
  h := FindWindow(nil, '接收窗口'); { 按標(biāo)題查找目標(biāo)窗口 }
  if h > 0 then
  begin
    Size := ByteLength(Edit1.Text) + 2;   { 多出的兩個(gè)字節(jié)用于后面的 #0 }
    CopyDataStruct.lpData := PChar(Edit1.Text + #0); { 要發(fā)送的字符串, #0 表示 PChar 結(jié)束}
    CopyDataStruct.dwData := WM_COPYDATA;            { 指定消息類型 }
    CopyDataStruct.cbData := Size;                   { 指定要發(fā)送的數(shù)據(jù)的大小 }
    SendMessage(h, WM_COPYDATA, 0, Integer(@CopyDataStruct)); { 發(fā)送 }
  end;
end;

end.

接收代碼:

---

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
  TForm1 = class(TForm)
    Memo1: TMemo;
    procedure FormCreate(Sender: TObject);
  private
  protected
    procedure WMCopyData(var Message: TWMCopyData); message WM_COPYDATA;
  public
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.FormCreate(Sender: TObject);
begin
  Caption := '接收窗口';
end;

procedure TForm1.WMCopyData(var Message: TWMCopyData);
begin
  Memo1.Lines.Add(PChar(Message.CopyDataStruct.lpData));
end;

end.

該代碼已在 Delphi 2010 下測(cè)試過(guò)了.

發(fā)現(xiàn) skymesh 朋友對(duì)消息操作不是太熟, 順便告知個(gè)小技巧(其實(shí)博客中可能早提到過(guò)):
在 TForm1 = class(TForm) ... end; 中執(zhí)行 Ctrl+空格;
然后輸入: wm...(譬如本例輸入 wmcopyd 即可) 后回車;
接著執(zhí)行 Ctrl+Shift+C, 會(huì)自動(dòng)完成上面大部分的消息代碼.

---